Полезные советы (96)

Как преобразовать в .NET Color в Brush? Просто:

Private Shared Function ColorToBrush(clr As System.Drawing.Color) As Brush
	Dim rgb As Integer = clr.ToArgb()
    Dim color = System.Windows.Media.Color.FromArgb(CByte(rgb >> 24 And &HFF), CByte(rgb >> 16 And &HFF), CByte(rgb >> 8 And &HFF), CByte(rgb And &HFF))
    Dim brsh As New SolidColorBrush(color) 
    Return brsh
End Function    

Чтобы сделать в WPF в панели меню какие-то пункты с выравниваеним по правому краю (например, меню «Справка» или «О программе»), можно описать в XAML произвольную панель элементов, как в примере ниже:

<Menu>

    <Menu.ItemsPanel>
        <ItemsPanelTemplate>
            <DockPanel />
        </ItemsPanelTemplate>
    </Menu.ItemsPanel>

    <MenuItem Header="Item1" />
    <MenuItem Header="Item2" />
    <MenuItem Header="Справка" HorizontalAlignment="Right" />
</Menu>

Часто необходимо перевести число из одной системы счисления в другую. Предлагается программный код статического класса, который реализует данную функциональность в виде статического метода ConvertFromTo(), а также дополнительных методов расширения.

''' <summary>
''' Вспомогательные.
''' </summary>
<Runtime.CompilerServices.Extension()>
Public Module Helpers

    ''' <summary>
    ''' Преобразует число из десятичной системы счисления в число в восьмеричной системе счисления.
    ''' </summary>
    <Runtime.CompilerServices.Extension()>
    Public Function ToOctal(dec As Integer) As Integer
        Return ConvertFromTo(dec, 10, 8)
    End Function

    ''' <summary>
    ''' Преобразует число из десятичной системы счисления в число в двоичной системе счисления.
    ''' </summary>
    <Runtime.CompilerServices.Extension()>
    Public Function ToBinary(dec As Integer) As Integer
        Return ConvertFromTo(dec, 10, 2)
    End Function

    ''' <summary>
    ''' Преобразует число из заданной системы счисления в другую.
    ''' </summary>
    ''' <param name="number">Число в исходной системе счисления.</param>
    ''' <param name="fromBase">Исходная система счисления.</param>
    ''' <param name="toBase">Целевая система счисления.</param>
    ''' <remarks>
    ''' Будьте внимательны: при переводе в двоичную систему может возникнуть ошибка переполнения, т.к. двоичные числа могут быть очень длинные.
    ''' Также здесь не реализован перевод чисел из и в 16-ную систему счисления, в которой применяется цифро-буквенная нотация.
    </remarks>
    Public Function ConvertFromTo(number As Integer, fromBase As Integer, toBase As Integer) As Integer
        Dim result As Integer = 0
        Dim i As Integer = 0
        Do While (number <> 0)
            result += (number Mod toBase) * CInt(Math.Pow(fromBase, i))
            number = CInt(Math.Truncate(number / toBase))
            i += 1
        Loop
        Return result
    End Function

End Module

Чтобы вместо стандартного MessageBox в приложении WPF использовать более современное и «красивое» окно, можно использовать средства самой Windows. Напишем класс-помощник, который будет выводить диалоговое окно, используя системную библиотеку comctl32.dll.

Imports System.Runtime.InteropServices

''' <summary>
''' "Красивое" диалоговое окно.
''' </summary>
Public Module TaskDialogHelper

    <DllImport("comctl32.dll", CharSet:=CharSet.Unicode, PreserveSig:=False)>
    Public Function TaskDialog(hwndParent As IntPtr, hInstance As IntPtr, title As String, mainInstruction As String, content As String, buttons As TaskDialogButtons, icon As TaskDialogIcon) As TaskDialogResult
    End Function

    Public Enum TaskDialogResult As Integer
        Ok = 1
        Cancel = 2
        Retry = 4
        Yes = 6
        No = 7
        Close = 8
    End Enum

    <Flags>
    Public Enum TaskDialogButtons As Integer
        Ok = &H1
        Yes = &H2
        No = &H4
        Cancel = &H8
        Retry = &H10
        Close = &H20
    End Enum

    Public Enum TaskDialogIcon As Integer
        Shield = 65532
        Information 
        [Error] 
        Warning 
    End Enum

End Module

Также в манифесте проекта необходимо раскомментировать следующий участок:

  <dependency>
    <dependentAssembly>
      <assemblyIdentity
          type="win32"
          name="Microsoft.Windows.Common-Controls"
          version="6.0.0.0"
          processorArchitecture="*"
          publicKeyToken="6595b64144ccf1df"
          language="*"
        />
    </dependentAssembly>
  </dependency>

Использовать код можно таким образом:

Dim dr = TaskDialogHelper.TaskDialog(New System.Windows.Interop.WindowInteropHelper(Me).Handle,
    IntPtr.Zero,
    "Лаконичный заголовок окна",
    "Здесь будет основной текст сообщения.",
    "А здесь вспомогательный.",
    TaskDialogHelper.TaskDialogButtons.Yes Or TaskDialogHelper.TaskDialogButtons.No,
    TaskDialogHelper.TaskDialogIcon.Information)

Желательно также при выводе данного окна проверять версию операционной системы: данное окно можно использовать в Windows Vista и более современных (версия больше 6):

If (System.Environment.OSVersion.Version.Major >= 6) Then 
    …